;
;    Mecrisp - A native code Forth implementation for MSP430 microcontrollers
;    Copyright (C) 2011  Matthias Koch
;
;    This program is free software: you can redistribute it and/or modify
;    it under the terms of the GNU General Public License as published by
;    the Free Software Foundation, either version 3 of the License, or
;    (at your option) any later version.
;
;    This program is distributed in the hope that it will be useful,
;    but WITHOUT ANY WARRANTY; without even the implied warranty of
;    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;    GNU General Public License for more details.
;
;    You should have received a copy of the GNU General Public License
;    along with this program.  If not, see <http://www.gnu.org/licenses/>.
;

; Enthält Routinen, die einen Einblick in das Innenleben ermöglichen.

writezahl macro Zahl
  pushda Zahl
  call #udot
  endm

;writebyte macro Zahl
;  decd r4
;  clr @r4
;  mov.b Zahl, @r4
;  call #udot
;  endm

;------------------------------------------------------------------------------
  Wortbirne Flag_visible, "words" ; ( -- ) Gibt die Wörterliste aus
;------------------------------------------------------------------------------
  push r10
  push &Base
  mov #16, &Base

  ifdef flashdictionaryeinbinden
  cmp #nBacklinkgrenze, &DictionaryPointer
  jhs +
  ; Fürs Ram:
    mov &Fadenende, r10
    jmp ++
+ ; Für den Flash
    mov #CoreDictionaryAnfang, r10
+
  else ; Wenn es nur das gewöhnliche Ram-Dictionary gibt
    mov &Fadenende, r10
  endif

  ; ( Fadenstück -- )

  ; r10 enthält die Adresse, an der die Liste beginnen soll.
  writeln ""

- ; Aufbau: Flags     Namenslänge
  ;         Name...   0
  ;         Link (zum Nachbarwort - nach vorn oder nach hinten ist egal)
  ;         Code

  ifdef flashdictionaryeinbinden
  ; Ist an der Stelle der Flags und der Namenslänge $FFFF ? Dann ist der Faden abgelaufen.
  cmp #0FFFFh, @r10
  je +
  endif

  ; Habe einen Dictionaryeintrag gefunden !
  write "Address: "
  writezahl r10
  write " Flags: "

  mov.b @r10+, r7
  writezahl r7
;  writebyte @r10
;  inc r10

  sub #4, r4     ; Genug Platz schaffen
  mov r10, 2(r4) ; Adresse für die Namensausgabe merken

  call #stringueberlesen_r10

  ; Angekommen im Linkfeld.
  write " Link: "
  mov @r10, @r4
  call #udot

  ; Schreibe noch die Codestartadresse.
  write " Code: "
  pushda r10
  incd @r4
  call #udot

  ; Codestartadresse ist mir einfach mal egal. Das war einmal.
  write " Name: "
  call #schreibestringmitlaenge

  writeln "" ; Zeilenende

  cmp #0FFFFh, @r10  ; -1 markiert Ende
  je +

  ; Folge dem Link
  mov @r10, r10
  jmp -

+ pop &Base
  pop r10
  ret

;------------------------------------------------------------------------------
  Wortbirne Flag_visible, ".s"
dotS: ; Zeichnet den Datenstack, benutzt für mich unsigned-Zahlen.
      ; Besonders nützlich für Logik, Adressen und Zähler.
;------------------------------------------------------------------------------
  push r10
  push r11
  mov #datenstackanfang, r10  ; Obere Adresse vom Stack.
  mov r10, r11                ; Duplikat anlegen
  sub r4, r11                 ; Datenstackpointer von der oberen Adresse abziehen ergibt Füllstand.

  write " Stack: ["

dotseinsprung:
  clrc
  rrc r11                     ; Füllstand durch 2 Teilen, da Stack Words aufnimmt.

  ; Habe nun den Pointer in r10, die Zahl der zu schreibenden Words in r11.

  push &Base      ; Füllstand schreiben
  mov #10, &Base
    writezahl r11
  pop &Base

  write "] "

  tst r11 ; Schon Null, Datenstack leer ?
  je +

- decd r10      ; Inhalt ausgeben:
  writezahl @r10

  dec r11
  jz +
  write ", "
  jmp -

+ writeln " *>"

  pop r11
  pop r10
  ret

;------------------------------------------------------------------------------
  Wortbirne Flag_visible, ".rs"
      ; Zeichnet den Returnstack, benutzt für mich unsigned-Zahlen.
      ; Besonders nützlich für Logik, Adressen und Zähler.            130 Bytes
;------------------------------------------------------------------------------
  push r10
  push r11
  mov #returnstackanfang, r10 ; Obere Adresse vom Stack.
  mov r10, r11                ; Duplikat anlegen
  sub sp, r11                 ; Stackpointer von der oberen Adresse abziehen ergibt Füllstand + 6.
  sub #6, r11                 ; Einsprung von .rs und die beiden gesicherten Register überspringen

  write " Returnstack: ["
  jmp dotseinsprung
