;
;    Mecrisp - A native code Forth implementation for MSP430 microcontrollers
;    Copyright (C) 2011  Matthias Koch
;
;    This program is free software: you can redistribute it and/or modify
;    it under the terms of the GNU General Public License as published by
;    the Free Software Foundation, either version 3 of the License, or
;    (at your option) any later version.
;
;    This program is distributed in the hope that it will be useful,
;    but WITHOUT ANY WARRANTY; without even the implied warranty of
;    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;    GNU General Public License for more details.
;
;    You should have received a copy of the GNU General Public License
;    along with this program.  If not, see <http://www.gnu.org/licenses/>.
;

; Logikfunktionen

;------------------------------------------------------------------------------
  Wortbirne Flag_visible_inline|Flag_foldable_1, "><" ; Swap Bytes.
  swpb @r4
  ret

;------------------------------------------------------------------------------
  Wortbirne Flag_visible|Flag_foldable_2, "rshift" ; ( x u -- x ) Schiebt x um u Stellen nach rechts

  clr r7
  xor @r4+, r7 ; Hole den Zähler - Im Prinzip wie mov, aber setzt Flags ! Wichtig, falls 0 Stellen geschoben werden sollen.
  jz +

- clrc
  rrc @r4
  jz +     ; Spare Takte und Platz, indem ich aufhöre, wenn das Geschobene Null geworden ist.
  dec r7  ; Zähler runtersetzen und prüfen
  jnz -

+ ret

;------------------------------------------------------------------------------
  Wortbirne Flag_visible|Flag_foldable_2, "lshift" ; ( x u -- x ) Schiebt x um u Stellen nach links

  clr r7
  xor @r4+, r7 ; Hole den Zähler - Im Prinzip wie mov, aber setzt Flags ! Wichtig, falls 0 Stellen geschoben werden sollen.
  jz +

- rla @r4
  jz +     ; Höre auf, wenn nichts mehr zum Schieben da ist.
  dec r7  ; Zähler runtersetzen und prüfen
  jnz -

+ ret

;------------------------------------------------------------------------------
  Wortbirne Flag_visible_inline|Flag_foldable_1, "shr"
  clrc
  rrc @r4
  ret

;------------------------------------------------------------------------------
  Wortbirne Flag_visible_inline|Flag_foldable_1, "shl"
  rla @r4
  ret

;------------------------------------------------------------------------------
  Wortbirne Flag_visible_inline|Flag_opcodierbar_rechenlogik, "bic" ; Könnte es auch andnot nennen.
  bic @r4+, 0(r4)
  ret

;------------------------------------------------------------------------------
  Wortbirne Flag_visible_inline|Flag_foldable_1, "not"
  inv @r4
  ret

;------------------------------------------------------------------------------
;  Wortbirne Flag_visible_inline|Flag_foldable_1, "invert" ; Einfach nur ein anderer Name für not
;  inv @r4
;  ret

;------------------------------------------------------------------------------
  Wortbirne Flag_visible_inline|Flag_opcodierbar_rechenlogik, "xor"
  xor @r4+, 0(r4)
  ret

;------------------------------------------------------------------------------
  Wortbirne Flag_visible_inline|Flag_opcodierbar_rechenlogik, "or"
  bis @r4+, 0(r4)
  ret

;------------------------------------------------------------------------------
  Wortbirne Flag_visible_inline|Flag_opcodierbar_rechenlogik, "and"
  and @r4+, 0(r4)
  ret
