@
@    Mecrisp-Stellaris - A native code Forth implementation for ARM-Cortex M microcontrollers
@    Copyright (C) 2013  Matthias Koch
@
@    This program is free software: you can redistribute it and/or modify
@    it under the terms of the GNU General Public License as published by
@    the Free Software Foundation, either version 3 of the License, or
@    (at your option) any later version.
@
@    This program is distributed in the hope that it will be useful,
@    but WITHOUT ANY WARRANTY; without even the implied warranty of
@    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
@    GNU General Public License for more details.
@
@    You should have received a copy of the GNU General Public License
@    along with this program.  If not, see <http://www.gnu.org/licenses/>.
@

@ Interpreter und Optimierungen
@ Interpreter and optimisations

@ -----------------------------------------------------------------------------
  Wortbirne Flag_visible, "evaluate" @ ( -- )
@ -----------------------------------------------------------------------------
  push {lr}
  bl source             @ Save current source

  @ 2>r
  ldm psp!, {r0}
  push {r0}
  push {tos}
  ldm psp!, {tos}

  ldr r0, =Pufferstand  @ Save >in and set to zero
  ldr r1, [r0]
  push {r1}
  movs r1, #0
  str r1, [r0]

  bl setsource          @ Set new source
  bl interpret          @ Interpret

  ldr r0, =Pufferstand  @ Restore >in
  pop {r1}
  str r1, [r0]

  @ 2r>
  pushdatos
  pop {tos}
  pop {r0}
  subs psp, #4
  str r0, [psp]

  bl setsource          @ Restore old source

  pop {pc}

@ -----------------------------------------------------------------------------
  Wortbirne Flag_visible, "interpret" @ ( -- )
interpret:
@ -----------------------------------------------------------------------------
  push {r4, r5, lr}

1:@ Bleibe solange in der Schleife, wie token noch etwas zurückliefert.
  @ Stay in loop as long token can fetch something from input buffer.

  @ Probe des Datenstackpointers.
  @ Check pointer for datastack.

  ldr r0, =datenstackanfang   @ Stacks fangen oben an und wachsen nach unten.
  cmp psp, r0                 @ Wenn die Adresse kleiner oder gleich der Anfangsadresse ist, ist alles okay.
  bls.n 2f
    Fehler_Quit_n "Stack underflow"

2:ldr r0, =datenstackende     @ Solange der Stackzeiger oberhalb des Endes liegt, ist alles okay.
  cmp psp, r0
  bhs.n 3f
    Fehler_Quit_N "Stack overflow"

3: @ Alles ok.  Stacks are fine.

@ -----------------------------------------------------------------------------

  @ Konstantenfaltungszeiger setzen, falls er das noch nicht ist.
  @ Set Constant-Folding-Pointer
  ldr r4, =konstantenfaltungszeiger
  ldr r5, [r4]
  cmp r5, #0
  bne.n 3f
    @ Konstantenfaltungszeiger setzen.
    @ If not set yet, set it now.
    movs r5, psp
    str r5, [r4]
3:

@ -----------------------------------------------------------------------------
  bl token
  @ ( Address Length )

  @ Prüfe, ob der String leer ist  Check if token is empty - that designates an empty input buffer.
  cmp tos, #0
  bne.n 2f
    ddrop
    pop {r4, r5, pc}
2:

@ -----------------------------------------------------------------------------
  @ String aus Token angekommen.  We have a string to interpret.
  @ ( Address Length )

  @ Registerkarte:
  @  r4: Adresse des Konstantenfaltungszeigers  Address of constant folding pointer
  @  r5: Konstantenfaltungszeiger               Constant folding pointer

  ddup
  bl find @ Probe, ob es sich um ein Wort aus dem Dictionary handelt:  Attemp to find token in dictionary.
  @ ( Token-Addr Token-Length Addr Flags )

  popda r1 @ Flags
  popda r2 @ Einsprungadresse

  @ ( Token-Addr Token-Length )

  @ Registerkarte:
  @  r1: Flags                                  Flags
  @  r2: Einsprungadresse                       Code entry point
  @  r4: Adresse des Konstantenfaltungszeigers  Address of constant folding pointer
  @  r5: Konstantenfaltungszeiger               Constant folding pointer

  cmp r2, #0
  bne.n 4f
    @ Nicht gefunden. Ein Fall für Number.
    @ Entry-Address is zero if not found ! Note that Flags have very special meanings in Mecrisp !

    ldr r0, [psp] @ Den String für die not-found Meldung vermerken.
    movs r1, tos

    bl sprungschreiber_flaggenerator @ Wenn noch mehr Faltkonstanten kommen, müssen die Ergebnisse von Vergleichen vorher geschrieben werden.

    bl number

  @ Number gives back ( 0 ) or ( x 1 ).
  @ Zero means: Not recognized.
  @ Note that literals actually are not written/compiled here.
  @ They are simply placed on stack and constant folding takes care of them later.

    popda r2   @ Flag von Number holen
    cmp r2, #0 @ Did number recognize the string ?
    bne.n 1b   @ Zahl gefunden, alles gut. Interpretschleife fortsetzen.  Finished.

    @ Number mochte das Token auch nicht.
not_found_addr_r0_len_r1:
@    pushda r0
@    pushda r1
    bl stype_addr_r0_len_r1
    Fehler_Quit_n " not found."

@ -----------------------------------------------------------------------------
4:@ Token im Dictionary gefunden. Found token in dictionary. Decide what to do.

  @ ( Token-Addr Token-Length )

  @ Registerkarte:
  @  r1: Flags                                  Flags
  @  r2: Einsprungadresse                       Code entry point
  @  r4: Adresse des Konstantenfaltungszeigers  Address of constant folding pointer
  @  r5: Konstantenfaltungszeiger               Constant folding pointer

  ldr r3, =state
  ldr r3, [r3]
  cmp r3, #0
  bne.n 5f
    @ Im Ausführzustand.  Execute.
    movs r5, #0   @ Konstantenfaltungszeiger löschen  Clear constant folding pointer
    str r5, [r4]  @ Do not collect literals for folding in execute mode. They simply stay on stack.


    @ Beginnt eine neue Definition mit : ?
    ldr r3, =Flag_Zustandswechsler & ~Flag_visible
    ands r3, r1
    beq.n .keindoppelpunkt

      @ writeln "Definitionsanfang-RA"
      ddrop
      ldr r0, =Datenstacksicherung @ Setzt den Füllstand des Datenstacks zur Probe.
      str psp, [r0]                @ Save current datastack pointer to detect structure mismatch later.

      bl create

      ldr r0, =state
      movs r1, #1 @ So eine Art bx lx-Kompilierzustand-Flag in State legen
      str r1, [r0]
      b.n 1b

.keindoppelpunkt:

    movs r3, #Flag_immediate_compileonly & ~Flag_visible
    ands r3, r1
    cmp r3, #Flag_immediate_compileonly & ~Flag_visible
    bne.n .ausfuehren
      bl stype
      Fehler_Quit_n " is compile-only."

.ausfuehren:
    ddrop
    pushda r2    @ Adresse zum Ausführen   Code entry point
    bl execute   @                         Execute it
    b.n 1b @ Interpretschleife fortsetzen.  Finished.

  @ Registerkarte:
  @  r0: Stringadresse des Tokens, wird ab hier nicht mehr benötigt.
  @      Wird danach für die Zahl der benötigten Konstanten für die Faltung genutzt.
  @      From now on, this is number of constants that would be needed for folding this definition
  @  r1: Flags
  @  r3: Temporärer Register, ab hier: Konstantenfüllstand  Constant fill gauge of Datastack
  @  r2: Einsprungadresse                        Code entry point
  @  r4: Adresse des Konstantenfaltungszeigers.  Address of constant folding pointer
  @  r5: Konstantenfaltungszeiger                Constant folding pointer

@ -----------------------------------------------------------------------------
5:@ Im Kompilierzustand.  In compile state.
    ddrop

    ldr r0, =Flag_Sprungschlucker & ~Flag_visible
    ands r0, r1
    bne.n .interpret_entsprungen
      bl sprungschreiber_flaggenerator

.interpret_entsprungen:
    @ Jetzt dürfen keine Sprünge mehr im Sprungtrampolin warten, falls sie nicht vom Allokator später eingebaut werden.



    @ Prüfe das Ramallot-Flag, das automatisch 0-faltbar bedeutet:
    @ Ramallot-Words always are 0-foldable !
    @ Check this first, as Ramallot is set together with foldability,
    @ but the meaning of the lower 4 bits is different.

    movs r0, #Flag_ramallot & ~Flag_visible
    ands r0, r1 @ Flagfeld auf Faltbarkeit hin prüfen
    bne.n .interpret_faltoptimierung

    @ Bestimme die Anzahl der zur Faltung bereitliegenden Konstanten:
    @ Calculate number of folding constants available.

    subs r3, r5, psp @ Konstantenfüllstandszeiger - Aktuellen Stackpointer
    lsrs r3, #2      @ Durch 4 teilen  Divide by 4 to get number of stack elements.
    @ Number of folding constants now available in r3.

    @ Prüfe die Faltbarkeit des aktuellen Tokens:
    @ Check for foldability.

    movs r0, #Flag_foldable & ~Flag_visible
    ands r0, r1 @ Flagfeld auf Faltbarkeit hin prüfen
    beq.n .interpret_allocator @ Not foldable, but maybe the allocator can handle this.

.interpret_genugkonstanten: @ Not opcodable. Maybe foldable.
      @ Prüfe, ob genug Konstanten da sind:
      @ How many constants are necessary to fold this word ?
      movs r0, #0x0F
      ands r0, r1 @ Zahl der benötigten Konstanten maskieren

      cmp r3, r0
      blo.n .interpret_allocator @ Not enough folding constants available, but maybe the allocator can handle this.

.interpret_faltoptimierung:
        @ Do folding by running the definition.
        @ Note that Constant-Folding-Pointer is already set to keep track of results calculated.
        pushda r2 @ Einsprungadresse bereitlegen  Code entry point
        bl execute @ Durch Ausführung falten      Fold by executing
        b.n 1b @ Interpretschleife weitermachen     Finished.



.interpret_allocator:

  @ All foldable cases are finished now.

  @ Flags of Definition in r1
  @ Entry-Point of Definition in r2
  @ Number of folding constants available in r3

  ldr r0, =Flag_allocator & ~Flag_visible
  ands r0, r1
  beq.n .interpret_allocator_finished

    bl nflush_faltkonstanten @ Jetzt werden die restlichen Faltkonstanten in den RA-Cache geschoben.
    @ Dies kommt einem partiellen Konstantenschreiben gleich, wobei allerdings die drei obersten Stackelemente
    @ TOS, NOS und 3OS im RA-Cache hängenbleiben. Dabei werden nur vielleicht Opcodes generiert, falls
    @ der RA-Cache zu klein ist, alle zu fassen.

    @ Der Allokatoreinsprung ist am Ende der Definition
    movs r0, r2
    bl suchedefinitionsende
    adds r2, r0, #1 @ One more for Thumb

    ldr r0, =allocator_base
    blx r2

    movs r0, psp  @ Keine Konstantenfaltung über den Allokator hinweg - sonst würde z.B. do/loop die Struktur nicht auf dem Stack lagern können.
    str r0, [r4]  @ Vor dem Aufschwimmen lassen den Konstantenfaltungszeiger neu setzen.

    bl nfaltkonstanten_aufschwimmen @ Sollten am Ende noch Faltkonstanten im Cache liegen, lasse sie aufschwimmen
    b.n 1b @ Interpretschleife weitermachen     Finished.

.interpret_allocator_finished:

  @ No optimizations possible. Go back to canonical stack for classic compilation.
  @ Write all folding constants left into dictionary.

  bl nflush_faltkonstanten     @ Vorhandene Faltkonstanten, soweit möglich, erstmal in den Registerallokator laden.
  bl tidyup_register_allocator @ Alle Registerbewegungen opcodieren

  movs r5, #0   @ Konstantenfaltungszeiger löschen  Clear constant folding pointer.
  str r5, [r4]

@ -----------------------------------------------------------------------------
  @ Write push {lr} if this definition still is in bx lr mode.

  ldr r0, =Flag_bxlr & ~Flag_visible
  ands r0, r1
  bne.n .prepared_for_classic
    bl push_lr_nachholen
.prepared_for_classic:

@ -----------------------------------------------------------------------------
  @ Classic compilation.
  pushda r2 @ Adresse zum klassischen Bearbeiten. Put code entry point on datastack.

  movs r2, #Flag_immediate & ~Flag_visible
  ands r2, r1
  beq.n 6f
    @ Es ist immediate. Immer ausführen. Always execute immediate definitions.
    bl execute @ Ausführen.
    b.n 1b @ Zurück in die Interpret-Schleife.  Finished.

6:movs r2, #Flag_inline & ~Flag_visible
  ands r2, r1
  beq.n 7f

  bl inlinekomma @ Direkt einfügen.        Inline the code
  b.n 1b @ Zurück in die Interpret-Schleife  Finished.

7:bl callkomma @ Klassisch einkompilieren  Simply compile a BL or Call.
  b.n 1b @ Zurück in die Interpret-Schleife  Finished.

@------------------------------------------------------------------------------
  Wortbirne Flag_visible|Flag_variable, "hook-quit" @ ( -- addr )
  CoreVariable hook_quit
@------------------------------------------------------------------------------
  pushdatos
  ldr tos, =hook_quit
  bx lr
  .word quit_innenschleife  @ Simple loop for default

@ -----------------------------------------------------------------------------
  Wortbirne Flag_visible, "quit" @ ( -- )
quit:
@ -----------------------------------------------------------------------------
  @ Endlosschleife - muss LR nicht sichern.  No need for saving LR as this is an endless loop.
  @ Stacks zurücksetzen
  @ Clear stacks and tidy up.
  .ifdef m0core
  ldr r0, =returnstackanfang
  mov sp, r0
  .else
  ldr sp, =returnstackanfang
  .endif

  ldr psp, =datenstackanfang

   @ Clear 16-Bit Flash write emulation value-and-location collection table
  .ifdef emulated16bitflashwrites
   bl sammeltabelleleeren
  .endif

  .ifdef universalflashinforth
  bl initflash
  .endif

  .ifdef flash16bytesblockwrite
  bl initflash
  .endif

  @ Base und State setzen

  ldr r0, =base
  movs r1, #10   @ Base decimal
  str r1, [r0]

  ldr r0, =state
  movs r1, #0    @ Execute mode
  str r1, [r0]

  ldr r0, =konstantenfaltungszeiger
  @ movs r1, #0  @ Clear constant folding pointer
  str r1, [r0]

  bl init_register_allocator

  ldr r0, =Pufferstand
  @ movs r1, #0  @ Set >IN to 0
  str r1, [r0]

  ldr r0, =current_source
  @ movs r1, #0  @ Empty TIB is source
  str r1, [r0]
  ldr r1, =Eingabepuffer
  str r1, [r0, #4]

quit_intern:
  ldr r0, =hook_quit
  ldr r0, [r0]
  mov pc, r0

quit_innenschleife:  @ Main loop of Forth system.
  bl query
  bl interpret
  writeln " ok."
  b.n quit_innenschleife
